Tutorial

Necessary imports

using DifferentiableFrankWolfe: DiffFW, simplex_projection
using ForwardDiff: ForwardDiff
using FrankWolfe: UnitSimplexOracle
using Test: @test
using Zygote: Zygote

Constructing the wrapper

f(x, θ) = 0.5 * sum(abs2, x - θ)  # minimizing the squared distance...
f_grad1(x, θ) = x - θ
lmo = UnitSimplexOracle(1.0)  # ... to the probability simplex
dfw = DiffFW(f, f_grad1, lmo);  # ... is equivalent to a simplex projection

Calling the wrapper

θ = rand(10)

10-element Vector{Float64}:
 0.9627230004562226
 0.11754347464908421
 0.2433210256226479
 0.9624576754382947
 0.9763309009038867
 0.4159546800119799
 0.7012120472149518
 0.3701613223473006
 0.904284867807034
 0.6923585428633326

frank_wolfe_kwargs = (max_iteration=100, epsilon=1e-4)
y = dfw(θ; frank_wolfe_kwargs)

10-element SparseArrays.SparseVector{Float64, Int64} with 4 stored entries:
  [1]  =  0.261342
  [4]  =  0.26104
  [5]  =  0.274855
  [9]  =  0.202763

y_true = simplex_projection(θ)
@test Vector(y) ≈ Vector(y_true) atol = 1e-3

Test Passed

Differentiating the wrapper

J1 = Zygote.jacobian(_θ -> dfw(_θ; frank_wolfe_kwargs), θ)[1]
J1_true = Zygote.jacobian(simplex_projection, θ)[1]
@test J1 ≈ J1_true atol = 1e-3

Test Passed

J2 = ForwardDiff.jacobian(_θ -> dfw(_θ; frank_wolfe_kwargs), θ)
J2_true = ForwardDiff.jacobian(simplex_projection, θ)
@test J2 ≈ J2_true atol = 1e-3

Test Passed

This page was generated using Literate.jl.